
/* 
Objective(s) -
-	This code demonstrates the alteration of Invoice Printing format
-	Default Invoice Format is overridden with a New Format

*/

;Add a new line in sales voucher type master to configure the customzied invoice format

[#Part	: VTYP BehaviourMain]            ;;;Line line is added to an existing part

;;;Syntax to add a new line after an existing line "VTYP Dec"

	Add	: Line : After 	:  VTYP Dec	:  Use Customize Invoice Format

;;;Difining the line "Use Customize Invoice Format"

[Line	:Use Customize Invoice Format]

	Field		: Medium Prompt,Use Customize Invoice Format

    ;;Locally setting the value in the field in line definition

    Local		: Field : Medium Prompt : Set As :  If NOT $$IsSales:$Parent then "" else "Use Customize Invoice format"


;Storage is defined in the field to store value

[Field	: Use Customize Invoice Format]

	Use			: Logical Field
	Storage	  	: IsCustomize

;;This field will be inactive if the vouchertype is not sales 

	Inactive	: NOT $$IsSales:$Parent 

;; Defining of User defined field  

[System	: UDF]

	IsCustomize : Logical: 1000


;Difining System Formula

[System	: Formula]

	IsCustomize :  $IsCustomize:VoucherType:##SVVoucherType = "Yes"

;;;;****************************************************************

; For enabling customized invoice printing for which "Use customized invoice format" is set Yes.

[#Form	:	 Sales Color]      ;;;Altering the existing sales invoice
	
	Option 		: SColor : @@IsCustomize

[!Form : SColor]

	Delete		:Print

;;for adding new report for printing 
	
	Add			:Print	:PkhrInvocie


;;Report Definition

[Report	: 	PkhrInvocie]

	Use         : Voucher
	
	Form		: PkhrForm

    PrintSet    : Report Title      : If NOT (##OptionalFlag) AND @@IsSales then $VchPrintTitle:VoucherType:##SVVoucherType else @@InvTitle  
    PrintSet    : Report SubTitle   : @@InvSubTitle
    PrintSet    : SVPrintCopies     : @@InvCopies
    Print       : VCHPrintConfigure
    Delete      : Set

;Form Definition

[Form	:	PkhrForm]

;;Declaring parts
	Parts		: Std Invoice Top,Pkhr VchTitle,Pkhr CompTitle, Pkhr BillDetails,Pkhr InvoiceTitle,  Pkhr Invoice
	Bottom Parts: Pkhr LedgerDetails,Pkhr AmtInWords, Pkhr BottomDetail
    
;;Setting the dimensions of the form
    Height      : 100% Page
    Width       : 100% Page  
    Space Top   : 0.25 inch 
    Space Right : 0.25 inch
    Space Left  : 0.5 inch
    Space Bottom: 0.5 inch
    
;;Page break is defined if multi page printing is required
 	Page Break	: Pkhr ClPageBreak ,Pkhr OpPageBreak

    Local       : Part      : Default   : PrePrintedBorder  : Yes
    Local       : Line      : Default   : PrePrintedBorder  : Yes
    Local       : Field     : Default   : PrePrintedBorder  : Yes

[ Part	: Pkhr ClPageBreak ]

	Line		: Pkhr ClPageBreak
    
;;Setting the border of the part to thin line

	Border		: Thin Top

[Line	:	Pkhr ClPageBreak ]

	Right Field	: Info Field
	Local 		: Field : Info Field : Info :  "Contd..."	

[ Part	: Pkhr OpPageBreak ]

	Part		: Std Invoice Top,Pkhr VchTitle,Pkhr CompTitle, Pkhr BillDetails,Pkhr InvoiceTitle
    
;;all the above parts will appear vertically

	Vertical	: Yes


[Part	: Pkhr CompTitle]

	Lines		:Pkhr CompTitle, Pkhr CompAddress 
    
;;Repeat attribute is use to repeat to multi line basically to display multiple line items

	Repeat 		: Pkhr CompAddress	: Company Address
	
[Line	: Pkhr CompTitle]

	Field		: Pkhr CompTitle
    
;;To assign some bottom space to the field 

	SpaceBottom	: 0.25

;;;for printing of Company Mailing Name

[Field	: Pkhr CompTitle]

	Use			: Name Field	
    
;;Syntax to set the value of a system formula

	Set as 		: @@CmpMailName
	Style	 	: Large Bold

;for making company name Large & Bold

	Local 		: Style : Large Bold : Height : 15
	FullWidth	: Yes 
	Align		: Centre
	Preprinted	: Yes	

[Line	: Pkhr CompAddress]

	Field		: Pkhr CompAddress

;For printing Company Address 

[Field	: Pkhr CompAddress]

;;Reuseablity of an existing template field "Name FIeld" which is already defined in default TDL. All the dimensions
;;are predefined.

	Use			: Name Field 
    
;;Setting the address value from storage to the field

	Set as		: $Address
    
;;Overriding the dimensions of name field

	Style		: Normal 
	FullWidth	: Yes  
	Width		: 100% Page
	Align		: Centre
	Preprinted	: Yes	

[Part	: Pkhr VchTitle]

	Line		: Pkhr CopyFld,Pkhr VchTitle


[Line	:Pkhr CopyFld]

	RightField	: CopyField
	Local		: Field : NameField	   : SetAs: "(Original/Duplicate/Triplicate)"
	Local		: Field : NameField	   : Preprinted: Yes
	Local		: Field : NameField	   : Width	: 31


[Line	: Pkhr VchTitle]

	Field		:Pkhr VchTitle

;;For Pringing Title of invoice

[Field	: Pkhr VchTitle]

	Use 		: Name Field
	Set As		: If $$IsEmpty:$VCHPrintTitle:VoucherType:$VoucherTypename Then @@InvTitle Else $VCHPrintTitle:VoucherType:$VoucherTypename
	Width		: 100% Page
	Align 		: Centre
	Style 		: Normal Bold
	Preprinted	: Yes	
	FullWidth	: Yes

;; for capturing Company CST/TIN no, Preauthentication details	

[Part	:Pkhr BillDetails]

	LeftPart	: Pkhr PartyInfo
	RightPart	: Pkhr BillDetail
	Vertical	: No
	Border		: ThinBox

[Part	: Pkhr PartyInfo]

	Part		: Pkhr PartyStat, Pkhr PartyDetail
	Width		: 64% Page
	Vertical	: Yes

[Part	: Pkhr PartyStat]

	Part		: Pkhr CstTin
	RightPart	: Pkhr Authentication
	Vertical	: No
	Border		: ThinBottom

[Part	: Pkhr CstTin]

	Width	: 35% Page
	Line	:  Pkhr Cst, Pkhr Tin

;; for printing CST No of Selected Company

[Line	: Pkhr Cst]

	Field		: ShortPrompt, NameField
	Local		: Field : ShortPrompt : Set As : "C.S.T. No"
	Local		: Field : ShortPrompt : PrePrinted : Yes
	Local		: FIeld : NameField	  : Set As : $InterStateSTNumber:Company:##SVCurrentCompany
	SpaceTop	: 2

;; for printing TIN No of Selected Company

[Line	: Pkhr Tin]

	Field	: ShortPrompt, NameField
	Local	: Field : ShortPrompt : Set As : "TIN. No"
	Local	: Field : ShortPrompt : PrePrinted : Yes
    
/*This $VatTinNumber:Company:##SVCurrentCompany syntax is used to pull
vat tin number from the company object when campany name is provided
*/

	Local	: FIeld : NameField	  : Set As : $VatTinNumber:Company:##SVCurrentCompany


[Part	: Pkhr Authentication]

	Width	: 25% Page
	Line	: Pkhr PreAuthen
	BottomLine: Pkhr StatusPartner, Pkhr NamePartner
	Border	: ThinLeft

[Line	: Pkhr PreAuthen]

	Field		: Name Field
	Local		:Field:NameField:Set as		: "Pre-authenticate"
	Local		:Field:NameField:FullWidth 	: Yes
	SpaceBottom	: 2

[Line	: Pkhr StatusPartner]

	Field		: Name Field
	Local		:Field:NameField:Set as		: "Status....Partner"
	Local		:Field:NameField:FullWidth 	: Yes

[Line	: Pkhr NamePartner]

	Field		: Name Field
	Local		:Field:NameField:Set as		: "Name.........."
	Local		:Field:NameField:FullWidth 	: Yes


;for printing Party Name, Address, Tin no & Phone no details


[Part	: Pkhr PartyDetail]

	Line	: Pkhr PartyName,Pkhr PartyAddress,Pkhr TinNo,Pkhr MobNo
	Repeat	: Pkhr PartyAddress : PartyAddress 

[Line	: Pkhr PartyName]

	Field	: Simple Prompt,Pkhr PartyName
	Local	: Field: Simple Prompt: Set As		:"To,M/s. "
	Local	: Field: Simple Prompt: Width		: 10% Page
	Local	: Field: Simple Prompt: Preprinted	: Yes


;for printing Party Name 
 
[Field	: Pkhr PartyName]

	Use		:   Name Field
	Set as		:   $PartyLedgerName
	Width		:   50% Page

[Line	: Pkhr PartyAddress]

	Field	: Simple Field ,NameField
	Local	: Field : NameField 	: Set As 	: $Address
	Local	: Field : NameField	: Style		: Normal
	Local	: Field : NameField	: Width		: 50% Page
	Local	: Field : Simple Field	: Set As 	: ""
	Local	: Field : Simple Field  : Width	 	: 10% Page
	Local	: Field : Simple Field  : Preprinted: Yes

;;For printing Tin No of Party 

	
[Line	:Pkhr TinNo]

	Field	: Simple Prompt,Pkhr TinNo
	Local	: Field: Simple Prompt: Set As		:"Tin No. "
	Local	: Field: Simple Prompt: Width		: 10% Page
	Local	: Field: Simple Prompt: Preprinted	: Yes
	Local	: Field: Simple Prompt: Invisible	:   If $$IsEmpty:$VatTinNumber:Ledger:$LedgerName Then Yes Else No


[Field 	: Pkhr TinNo]

	Use		: Name Field
	Set as		: $VatTinNumber:Ledger:$LedgerName
	Invisible	: If $$IsEmpty:$VatTinNumber:Ledger:$LedgerName Then Yes Else No
	Width		: 50% Page

;;For printing Phone No of Party 


[Line	: Pkhr MobNo]

	Field	: Simple Prompt,Pkhr MobNo
	Local	: Field: Simple Prompt: Set As		:"Ph./Mob. "
	Local	: Field: Simple Prompt: Width		: 10% Page
	Local	: Field: Simple Prompt: Preprinted	: Yes
	Local	: Field: Simple Prompt: Invisible	: If $$IsEmpty:$LedgerPhone:Ledger:$LedgerName Then Yes Else No

[Field	: Pkhr MobNo]

	Use		: Name Field
	Set as		: $LedgerPhone:Ledger:$LedgerName
	Invisible	: If $$IsEmpty:$LedgerPhone:Ledger:$LedgerName Then Yes Else No
	Width		: 50% Page

;; for printing Invoice no, Invoice Date, Delivery Challan no etc

[Part	: Pkhr BillDetail]

	Line		: Pkhr BookNo,Pkhr VchNo,Pkhr VchDate,Pkhr ChallanNo,Pkhr ChallanDate
	Width		: 36% Page
	Border		: ThinLeft

;for printing Book No

[Line	: Pkhr BookNo]

	RightField	: MediumPrompt, Pkhr BookNo
	Local		: Field : MediumPrompt : Set As : "Book No."
	Local		: Field : MediumPrompt : Style	: NormalBold
	Local		: Field : MediumPrompt : Preprinted: Yes	
	Local		: Field : MediumPrompt : Width	: 10% Page
	SpaceTop	: 1
	Space Bottom: 1

[Field	: Pkhr BookNo]

	Use		: Short Name Field
	Set As		: $BookNumber
	Width		: 25% Page
	Style		: NOrmal

;for printing Invoice Number/Voucher Number


[Line	: Pkhr VchNo]

	RightField	: MediumPrompt, Pkhr VchNo
	Local		: Field : MediumPrompt : Set As : "Serial No."
	Local		: Field : MediumPrompt : Style	: NormalBold
	Local		: Field : MediumPrompt : Preprinted: Yes	
	Local		: Field : MediumPrompt : Width	: 10% Page
	Space Bottom: 1

[Field	: Pkhr VchNo]

	Use		: Short Name Field
	Set As		: $VoucherNumber
	Width		: 25% Page
	Style		: NOrmal


;for printing Delivery Note (Challan) Number

[Line: Pkhr ChallanNo]

	
	RightField		: Pkhr ChallanNoT, Pkhr ChallanNo
	Space Bottom: 1


[Field: Pkhr ChallanNoT]
		
	Use		:  MediumPrompt
	Set As		:  "Challan No."
	Style		:  NormalBold
	Preprinted	:  Yes	
	Width		: 10% Page

[Field: Pkhr ChallanNo]

	Use		: ShortName Field
	Set As		: $BasicShipDeliveryNote
	Width		: 25% Page
	Style		: NOrmal


;;For Printing Invoice Date

[Line	: Pkhr VchDate]

	RightField		: Pkhr InvOrderDtString, Pkhr InvOrderDate
	Space Bottom: 1

[Field: Pkhr InvOrderDtString]


	Use		: MediumPrompt
	info		: "Date"
	Style		: NormalBold
	Align		: Left
	Preprinted	: Yes	
	Width		: 10% Page

[Field: Pkhr InvOrderDate]

	Use		: Short Date Field
	Set As		: $Date
	Align		: Left
	Width		: 25% Page
	Style		: NOrmal


;;For Printing Delivery Note (Challan) Date


[Line	: Pkhr ChallanDate]

	RightField	: Pkhr ChallanDateT, Pkhr ChallanDate
	Space Bottom: 1

[Field: Pkhr ChallanDateT]


	Use		: MediumPrompt
	info		: "Date"
	Align		: Left
	Preprinted	: Yes	
	Width		: 10% Page
	Style		: NOrmalBold

[Field: Pkhr ChallanDate]

	Use		: Name Field
	Set As		: $BasicShippingDate
 	Align		: Left
	Width		: 25% Page
	Style		: Normal


;for printing Column Titles like, Sl. no, Particulars, Quantity, Weight, Rate, Value

[ Part 	: Pkhr InvoiceTitle]

	Lines 		:Pkhr InvoiceTitle 

[ Line 	: Pkhr InvoiceTitle]

	Fields 			:	Pkhr SNo,Pkhr Desc  
	Right Fields 	:   Pkhr Qty,Pkhr Rate,  Pkhr Amt
	Local : Field : Default		: Type   : String
	Local : Field : Default		: Style	 : Normal Bold
	Local : Field : Default		: Align  : Centre

	Local : Field : Pkhr SNo	: Set As : "S.No."
	Local : Field : Pkhr SNo 	: Preprinted: Yes	
	Local : Field : Pkhr Desc  	: Set as : "PARTICULARS"
	Local : Field : Pkhr Desc 	: Preprinted: Yes	
	Local : Field : Pkhr Qty	: Set as : "WT."
	Local : Field : Pkhr Qty 	: Preprinted: Yes	
	Local : Field : Pkhr Unit	: Set As : "Unit"
	Local : Field : Pkhr Unit	: PrePrinted : Yes
	Local : Field : Pkhr Rate  	: Set as : "RATE"
	Local :	Field : Pkhr Rate 	: Preprinted: Yes	
	Local : Field : Pkhr Amt   	: Set as : "AMOUNT"
	Local :	Field : Pkhr Amt 	: Preprinted: Yes	
	Border 			:	Column Titles


;;for printing Item Details like, Stock item Name, Quantity, Rate, Amount


[ Part : Pkhr Invoice ] 

		Line 		: 	Pkhr Details 
		Repeat		:	Pkhr Details : InventoryEntries
		Scroll		:   	Vertical
		CommonBorder	:	Yes
		Float		:	No
		Total 		: 	Pkhr Amt , Pkhr Qty 


[ Line : Pkhr Details ]

	Fields 			:	Pkhr SNo,Pkhr Desc  
	Right Fields 		:	Pkhr Qty, Pkhr Rate,  Pkhr Amt
	
; for priting user description of stock item

	Explode			: Pkhr Description 	: NOT $$IsEmpty:$StockItemName AND Not $$IsEmpty:$BasicUserDescription And ##ICFGAddlDesc

; for printing Batch details of stock item

	Explode			: Pkhr BatchDetails	: (@@HasBatchWise OR @@IsOrderVch) AND @@InvWithBatches AND (NOT @@IsOrderVch OR @@OrdExplBatch)

;for printing Alternate Quantity details

	Explode			: Pkhr AltQty	  	: @@InvWithQty AND NOT $$IsEmpty:$StockItemName AND NOT @@NoAltUnits


;;for printing additional Description of stock item

[Part: Pkhr Description]

	Line	: Pkhr Description
	Repeat	: Pkhr Description	: User Description
        BreakOn : $$IsEmpty:$BasicUserDescription
        Scroll  : Vertical


[Line:  Pkhr Description]

	Field :Pkhr SNo,	Pkhr Description
	Local : Field : Pkhr SNo : Set As : " "


[Field: Pkhr Description]

	Use     : Name Field
    	Style   : Small Italic
        Storage : BasicUserDescription
        Set as  : if (($$ExplodeLevel = 0) AND ($$Line = 1)) then $Description:StockItem:$StockItemName else $$Value
	Width 	: 40% Page


;;for printing batch details of stock item


[Part: Pkhr BatchDetails]

	Line	: MIT BatchDetails
	Repeat	: MIT BatchDetails: Batch Allocations

[Line: MIT BatchDetails]
	
	Fields 			    	: Pkhr Sno,Pkhr Desc  
	Right Fields 			: Pkhr Qty, Pkhr Rate,  Pkhr Amt
	Local	: Field: Pkhr Sno	: Set As: " "
	Local	: Field: Pkhr Desc	: Set As:$BatchName
	Local	: Field: Pkhr Desc	: Style : Small Bold
	Local	: Field: Pkhr Qty	: Style : Small  
	Local	: Field: Pkhr Unit	: Set As: " " 
	Local	: Field: Pkhr Rate	: Set As: " "
	Local	: Field: Pkhr Amt	: Set As: " "



;;for printing alternate unit details


[Part: Pkhr AltQty]
	
	Line: Pkhr AltQty

[Line: Pkhr AltQty]

	
	Fields 			:	Pkhr Sno,Pkhr Desc  
	Right Fields 	:	Pkhr AltQty, Pkhr Rate,  Pkhr Amt
	Local	: Field: Pkhr Sno	: Set As: " " 
	Local	: Field: Pkhr Desc	: Set As: " "
	Local	: Field: Pkhr Qty	: Set As: " "
	Local	: Field: Pkhr Unit	: Set As: " "
	Local	: Field: Pkhr Rate	: Set As: " "
	Local	: Field: Pkhr Amt	: Set As: " "


[Field: Pkhr AltQty]


    Use         : QtySecondaryField
    Align       : Centre
    Style       : Small Italic
    Format      : "Bracketed,NoZero,Symbol,ShortForm"
    Set as      : $BilledQty
    Set always  : Yes
    Skip        : Yes
    Inactive    : $$IsEnd:$StockItemName OR @@NoAltUnits
    Invisible   : NOT @@InvWithQty
    Width	: 15% Page
    Border	: Thin Left


;for printing Sl.No.

[Field	: Pkhr SNo]
	Use 			: 	Name Field
	Set As			:   $$Line
	Width 			:   10% Page
	Border			: ThinLeft


;for printing Stock Item Name ;Sl.No.

[ Field : Pkhr Desc ]

	Use 			: 	Name Field
	Set As			:   If $$IsEmpty:$Description:StockItem:$StockItemName Then $StockItemName Else $Description:StockItem:$StockItemName
	Width 			:	40% Page
	Border			: 	Thin Left


;for printing Billed Quantity

[ Field : Pkhr Qty ]

	Use 			:	Qty Primary Field
 	Set as	 		:	$BilledQty
	Style			:	NOrmal Bold
	Width			:	15% Page
	Align			:	Centre
	Border			:	Thin Left

;for printing Rate

[ Field : Pkhr Rate ]

	Use			: Rate Price Field
	Set as 			: $Rate
        Width			: 15% Page
	Align			: Right
	Border			: Thin Left
	

;for printing Amount


[ Field : Pkhr Amt]
	
	Use 			:	Amount Base Field
	Set as 			:	$Amount
	Width			:	20% Page
	Border 			:	Thin LeftRight

;This part is used for printing ledger Entries like Discount, VAT, Etc.

[Part	: Pkhr LedgerDetails]

	Left Part	: Pkhr BlnkPart
	Right Part	: Pkhr AccDetails
	Vertical	: NO
	Border		: ThinBox

[Part	: Pkhr BlnkPart]

	Width	: 40% Page
	Line	: Pkhr BlnkPart

[Line	: Pkhr BlnkPart]

	FIeld	: Pkhr BlnkPart

[Field 	: Pkhr BlnkPart]

	Set As : ""


[Part	: Pkhr AccDetails]

	Lines 	: Pkhr Total,Pkhr AccDetails, Pkhr GrandTotal
	Repeat 	: Pkhr AccDetails:Ledger Entries
	Total 	: Pkhr AccVal
	Width	: 60% Page

[Line: Pkhr Total]

	Right Fields: Pkhr AccLess,Totd,Pkhr AccRate,Pkhr AccPerSign, TotNo
	Local	: Field : Pkhr AccLess : Set As : " "
	Local	: Field : Pkhr AccRate : Set As : " " 
	Local	: Field : Pkhr AccPerSign :Set As : " " 
	Space Top	: 0.25

[Field: Totd]

	Use	: NameField
	Set As	: "Total"
	Style	: Normal Bold  
 	Width	: 25% Page

[FIEld: TotNo]

	Use 	:	Amount Base Field
	Set As 	:	$$Total:PkhrAmt
	Style	: 	Normal
	Width	: 	20% Page

[ Line : Pkhr ACCDetails ]
 
	Right Fields 	: Pkhr AccLess,PkhrAccDet,Pkhr AccRate,Pkhr AccPerSign,  PkhrAccVal

;for printing "Less" if discount is given.

 
[Field :Pkhr AccLess]
	

	Use 	:	 Simple Field
	Width 	:	 5% Page
	Set as 	:	 If $Amount< 0 then "Less" else ""
	Style 	:	 Small Italic
	Align 	:	 Right

;for printing ledgername 

[Field : Pkhr ACCDet]

	Use	:	NameField
	Set as 	:	If Not $$IsSysName:$LedgerName then $LedgerName else ""
	Align 	:	Left
	WIdth	:       25% Page

;for printing rate of tax 

[Field: Pkhr AccRate]


    Use         : Rate Price Field
    Type        : Number
    Align       : Right
    Format      : "NoZero,Decimals:-1"
    Style       : Normal Italic   

;;$$CollectionField:$TDSTaxRate:1:TaxBillAllocations

/*
$$CollectionField is internal function which is used to provide some value from a collection
 This function will provide the first TDS rate from the collection "TaxBillAllocations"

*/
	  Set as      : if ##SATCSDetails AND @@TaxLedgerHasTCS then $$CollectionField:$TDSTaxRate:1:TaxBillAllocations else +
				  $BasicRateOfInvoiceTax
	  Inactive    : $$IsSysName:$LedgerName
	  Invisible   : NOT @@InvWithRate
	  Width	      : 5% page


[Field: Pkhr AccPerSign]

    Use         : Rate Units Field
    Type        : String
    Align       : Left
    Style       : Normal Italic
    Set as      : if $$IsEmpty:$BasicRateOfInvoiceTax then " " else "%"
    Inactive    : $$IsSysName:$LedgerName
    Invisible   : NOT @@InvWithRate
    Width	: 5% page


;for printing amount

[Field : Pkhr ACCVal ]

	Use 	: Amount Base Field
	Storage : Amount
	Style	: Normal
	Width	: 20% Page


;Grand Total line 

[Line: Pkhr GrandTotal]

	Space Top		:1
	Right Fields 	:Pkhr AccLess, Pkhr AccDet,Pkhr AccRate,Pkhr AccPerSign, Pkhr AccVal
	Local	: Field : Pkhr AccLess 		: Set As  : " "
	Local	: Field : Pkhr AccRate 		: Set As  : " " 
	Local	: Field : Pkhr AccPerSign	: Set As  : " "  
	Local	: Field : Pkhr AccDet 		: Set As  : "G.Total"
	Local	: Field : Pkhr AccDet 		: Style	  : Normal Bold
 	Local	: Field : PkhrAccVal		: Set As  : #EXRPNVINVTotal
	Local	: Field : PkhrAccVal		: Border  : Totals

;;****************************************************************************

;for printing Amount in words


[Part	: Pkhr AmtInWords]

	Line		: Pkhr AmtInWords
	Border		: ThinLeftRight

[Line	: Pkhr AmtInWords]

	Field	: Name Field
	Local	:Field:NameField:Set as		: "Rs.(In words) "+$$InWords:#EXPINVINVTotal:"NoSymbol" + " Only"
	Local	:Field:NameField:FullWidth 	: Yes
	SpaceTop	: 0.5
	SpaceBottom	: 0.5

;;****************************************************************************

;;for printing declaration, authorised signatory details, Other terms & Condition details etc


[Part	: Pkhr BottomDetail]

	Parts	: Pkhr Declaration, Pkhr Signatory
	Border	: ThinBox
	Vertical: No

[Part	:Pkhr Declaration]

	Line	: Pkhr JurisStr,Pkhr Note,Pkhr Note1,Pkhr Note2
	Width	: 70% Page

[Line	: Pkhr JurisStr]

	Field	: NameField
	Local	: Field : NameField : Set AS 	:  "All Subject to "+@@Jurisdiction+" Jurisdiction"
	Local	: Field : NameField : Invisible	: $$IsEmpty:@@Jurisdiction
	Local	: Field : NameField : Width	 	: 50% Page
	Local	: Field : NameField : Preprinted: Yes


[Line	: Pkhr Note]
	
	Field	: MediumPrompt,NameField
	Local	: Field	: MediumPrompt : Set As : "Note"
	Local	: Field : MediumPRompt : Style	: Normal
	Local	: Field : MediumPRompt : Width	: 10% Page
	Local	: Field : NameField    : Set AS :  "(1) Goods once sold cannot be taken back."
	Local	: Field : NameField    : Style	: Normal
	Local	: Field : NameField    : Preprinted: Yes
	Local	: Field : NameField    : Width	: 40% Page

[Line	: Pkhr Note1]
	
	Field	: MediumPrompt,NameField
	Local	: Field	: MediumPrompt : Set As : " "
	Local	: Field : MediumPRompt : Style	: Normal
	Local	: Field : MediumPRompt : Width	: 10% Page
	Local	: Field : NameField    : Set AS :  "(2) Interest will be charge @ 12% if bill is not paid with in time."
	Local	: Field : NameField    : Style	: Normal
	Local	: Field : NameField    : Preprinted: Yes
	Local	: Field : NameField    : Lines	: 0
	Local	: Field : NameField    : Width	: 40% Page

[Line	: Pkhr Note2]
	
	Field	: MediumPrompt,NameField
	Local	: Field	: MediumPrompt : Set As : " "
	Local	: Field : MediumPRompt : Style	: Normal
	Local	: Field : MediumPRompt : Width	: 10% Page
	Local	: Field : NameField    : Set AS : "(3) E.& O.E."
	Local	: Field : NameField    : Style	: Normal
	Local	: Field : NameField    : Preprinted: Yes
	Local	: Field : NameField    : Lines	: 0
	Local	: Field : NameField    : Width	: 40% Page



[Part	: Pkhr Signatory]

	Width		: 30% Page
	Line		: PkhrSignAuthn 
	BottomLine	: Pkhr Status, Pkhr SignName
	
[Line	: PkhrSignAuthn]

	Field		: Name Field
	Local		:Field:NameField:Set as		: "Signature of Person issuing"
	Local		:Field:NameField:FullWidth 	: Yes
	SpaceBottom	: 2

[Line	: Pkhr Status]

	Field		: Name Field
	Local		:Field:NameField:Set as		: "Status....."
	Local		:Field:NameField:FullWidth 	: Yes

[Line	: Pkhr SignName]

	Field		: Name Field
	Local		:Field:NameField:Set as		: "Name.................."
	Local		:Field:NameField:FullWidth 	: Yes
