;; Sri Ganeshji : Sri Balaji : Sri Pitreshwarji : Sri Durgaji : Sri Venkateshwara

;;A User-defined Field definition

[System: UDF]
    DepRate: Number: 1005

;;Modify the Part in the Default Tally TDL and add a new line

[#Part: Led Other Details]
    Add: Line: DepRate

;;Line contains two fields
;;One to display caption and the other to accept user-input

[Line: DepRate]
    Field: Short Prompt, DepRate
    Local: Field: Short Prompt: Set as: "DepRate"

;;Field to accept User-input

[Field: DepRate]
    Use: Number Field
    Storage: DepRate

;;Altering Menu Item to Invoke the Report

[#Menu : Gateway of Tally]
	
	Add : Item : After : @@LocRatioAnalysis : Depreciation : Display : Dep Report

;;Writing A Report

[Report : Dep Report]
	
	Use	 : DSP Template
	Variable : SVFromDate, SVToDate
	Set      : SVfromDate : ##SVCurrentdate
	Set      : SVToDate : ##SVCurrentdate
	Form     : Dep Form
[Form : Dep Form]
	Use 	    : DSP Template	
	Height 	    : 100% Screen
    	Width	    : 100% Screen
	BackGround  : Lily White
	Space Top   : If $$InPrintMode Then 0.5 Else 0 inches
	Button      : PrintButton, ExportButton,F2 ChangePeriod
	Parts       : Dep Tit,DepinfoReport
		
[Part : Dep Tit]
	
	Space Bottom : 0.2 inch
	Line : Dep Tit Line,DepDate
    
	
[Line : Dep Tit Line]
	
	Field : Dep Tit Field
	
[Field : Dep Tit Field]
	
	Use        : Name Field
	Set as     : "DEPRECIATION CHART"
	Align      : Center
	Full Width : Yes
	Style      : Large Bold

[Line : DepDate]
	
			 Space Top: 1% page
			 Field : DepFromdt,ToField,DepTodt
			 
[Field : DepFromdt]
	
   			  Use       : Date Field 
	          Set as    : ##SVCurrentdate
	          Width     : 45% Screen
	          Align     : Center
	          Style     : Normal 
			  
[Field : ToField]
	
	Use    : Name Field
	Set as : "To"
	Width  : 4% Screen
	Align  : Center
	Style  : Normal

[Field : DepTodt]
	
	Use       : Date Field 
	Set as    : ##SVToDate
	Width     : 45% Screen
	Align     : Center
	Style     : Normal 

[Part :  DepInfoReport]
	
	Line      : DepcolumnTitles,DepInfo
	Repeat    : DepInfo  : Mycollection    
	Scroll    : Both
	Common Border : Yes
	Float     : No
	Border    : Thin Box
    Bottom Line:COlTotals
	Total :Op.Bal.,Addition,Sale,Total,Depreciation,Closing Bal

[Line : DepColumnTitles]
	
	Border : Column Titles 
	
	Fields : SerialNo.,Particulars,Dep.Rate,Op.Bal.,Addition,Sale,Total,Depreciation,Closing Bal
	
	Local : Field : SerialNo.     : Set as 	   : "SNo." 
	Local : Field : SerialNo.     : Line       : 0
	Local : Field : Particulars   : Set as     : "Particulars"
	Local : Field : Particulars   : Line       : 0
	Local : Field : Dep.Rate      : Set as     : "Dep.Rate"
	Local : Field : Op.Bal.       : Set as     : "Op.Bal."
	Local : Field : Addition      : Set as     : "Addition"
	Local : Field : Sale  	      : Set as     : "Sale"
	Local : Field : Total         : Set as     : "Total"
	Local : Field : Depreciation  : Set as     : "Depreciation"
	Local : Field : Closing Bal   : Set as     : "Closing Bal"
	Local : Field : Default	      : Type  	   : String
	Local : Field : Default       : Style 	   : Small 
	Local : Field : Default	      : Align 	   : Center
	
[Line : DepInfo]

	Fields : SerialNo.,Particulars,Dep.Rate,Op.Bal.,Addition,Sale,Total,Depreciation,Closing Bal
			
		
[Line: COlTotals]

	Use   :  DepColumnTitles

	Local : Field : SerialNo. 	: Set as: "" 
	Local : Field : Particulars     : Set as: "Grand Total"
	Local : Field : Dep.Rate 	: Set as: ""
	Local : Field : Op.Bal. 	: Set as: $$Total:Op.Bal.
	Local : Field : Addition	: Set as: $$Total:Addition
	Local : Field : Total   	: Set as: $$Total:Total 
	Local : Field : Sale    	: Set as: $$Total:Sale
	Local : Field : Depreciation    : Set as: $$Total:Depreciation
	Local : Field : Closing Bal	: Set as: $$Total:ClosingBal

[Field : SerialNo.]
		
	Use    : Number Field
	Set as : $$Line
	Width  : 4% Screen
	Style  : Normal
	
[Field : Particulars]
		
	Use : Name Field
	Set as : $Name
	Width  : 25% Screen
	Style  : Normal
	Border : Thin Left
	
[Field : Dep.Rate]
		
	Use : Number Field
	Set as : $DepRate
	Width  : 5% Screen
	Style  : Normal
	Border : Thin Left
	
[Field : Op.Bal.]
		
	Use    : Amount Field
	Set as : $BSOpening
	Width  : 10% Screen
	Style  : Normal
	Border : Thin Left
	
[Field : Addition]
		
	Use    : Amount Field
	Set as : $BSDebits
	Width  : 10% Screen
	Style  : Normal
	Border : Thin Left
[Field : Sale]
		
	Use    : Amount Field
	Set as : $BSCredits
	Width  : 10% Screen
	Style  : Normal
	Border : Thin Left
	
[Field : Total]
		
	Use : Amount Field
	Set as : ($BSOpening + $BSDebits) - $BSCredits 
	Width : 12% Screen
	Style : Normal
	Border  :  Thin Left
	
[Field : Depreciation]
		
	Use : Amount Field
	Set as : (#Total * #Dep.Rate) / 100
	Width : 12% Screen
	Style : Normal
	Border  :  Thin Left

[Field : Closing Bal]
	
    Use : Amount Field
	Set as : #Total - #Depreciation
	Width  : 12% Screen
	Style  : Normal
	Border : Thin Left

[Collection : Mycollection]
	
	Type		   : Ledger 	
	Child Of	   : $$GroupFixedAssets
	Belongs To	   : Yes
	

;; EOF
